[MathJax on]

4 Examples

Several classes of examples of subgroups of \mathrm{Aut}(B_{d,k}) that satisfy (C) and or (D) are constructed in [Tor20] and implemented in this section. For a given permutation group F\le S_{d}, there are always the three local actions \Gamma(F), \Delta(F) and \Phi(F) on \mathrm{Aut}(B_{d,2}) that project onto F. For some F, these are all distinct and yield all universal groups that have F as their 1-local action, see [Tor20, Theorem 3.32]. More examples arise in particular when either point stabilizers in F are not simple, F preserves a partition, or F is not perfect. This section also includes functions to provide the k-local actions of the groups \mathrm{PGL}(2,\mathbb{Q}_{p}) and \mathrm{PSL}(2,\mathbb{Q}_{p}) acting on T_{p+1}.

4.1 Discrete groups

Here, we implement the local actions \Gamma(F),\Delta(F)\le\mathrm{Aut}(B_{d,2}), both of which satisfy both (C) and (D), see [Tor20, Section 3.4.1].

4.1-1 LocalActionElement

for the arguments d, a

Returns: the automorphism \gamma(a)=(a,(a)_{\omega\in\Omega})\in\mathrm{Aut}(B_{d,2}).

The arguments of this method are a degree d \in\mathbb{N}_{\ge 3} and a permutation a \in S_d.

for the arguments l, d, a

Returns: the automorphism \gamma^{l}(a)\in\mathrm{Aut}(B_{d,l}) all of whose 1-local actions are given by a.

The arguments of this method are a radius l \in\mathbb{N}, a degree d \in\mathbb{N}_{\ge 3} and a permutation a \in S_d.

for the arguments l, d, s, addr

Returns: the automorphism of B_{d,l} whose 1-local actions are given by s at vertices whose address has addr as a prefix and are trivial elsewhere.

The arguments of this method are a radius l \in\mathbb{N}, a degree d \in\mathbb{N}_{\ge 3}, a permutation s \in S_d and an address addr of a vertex in B_{d,l} whose last entry is fixed by s.

for the arguments d, k, aut, z

Returns: the automorphism \gamma_{z}(aut)=(aut,(z(aut,\omega))_{\omega\in\Omega})\in\mathrm{Aut}(B_{d,k+1}).

The arguments of this method are a degree d \in\mathbb{N}_{\ge 3}, a radius k \in\mathbb{N}, an automorphism aut of B_{d,k}, and an involutive compatibility cocycle z of a subgroup of \mathrm{Aut}(B_{d,k}) that contains aut (see InvolutiveCompatibilityCocycle (5.3-1)).

gap> LocalActionElement(3,(1,2));
(1,3)(2,4)(5,6)

gap> LocalActionElement(2,3,(1,2));
(1,3)(2,4)(5,6)
gap> LocalActionElement(3,3,(1,2));
(1,5)(2,6)(3,8)(4,7)(9,11)(10,12)

gap> LocalActionElement(3,3,(1,2),[1,3]);
(3,4)
gap> LocalActionElement(3,3,(1,2),[]);
(1,5)(2,6)(3,8)(4,7)(9,11)(10,12)

gap> S3:=LocalAction(3,1,SymmetricGroup(3));;
gap> z1:=AllInvolutiveCompatibilityCocycles(S3)[1];;
gap> LocalActionElement(3,1,(1,2),z1);
(1,4)(2,3)(5,6)
gap> z3:=AllInvolutiveCompatibilityCocycles(S3)[3];;
gap> LocalActionElement(3,1,(1,2),z3);
(1,3)(2,4)(5,6)

4.1-2 LocalActionGamma

for the arguments d, F

Returns: the local action \Gamma(F)=\{(a,(a)_{\omega})\mid a\in F\}\le\mathrm{Aut}(B_{d,2}).

The arguments of this method are a degree d \in\mathbb{N}_{\ge 3}, and a subgroup F of S_{d}.

for the arguments l, d, F

Returns: the group \Gamma^{l}(F)\le\mathrm{Aut}(B_{d,l}).

The arguments of this method are a radius l \in\mathbb{N}, a degree d \in\mathbb{N}_{\ge 3}, and a subgroup F of S_d.

for the arguments F, z

Returns: the group \Gamma_{z}(F)=\{(a,(z(a,\omega))_{\omega\in\Omega})\mid a\inF\}\le\mathrm{Aut}(B_{d,k+1}).

The arguments of this method are a local action F \le\mathrm{Aut}(B_{d,k}) and an involutive compatibility cocycle z of F (see InvolutiveCompatibilityCocycle (5.3-1)).

gap> F:=TransitiveGroup(4,3);;
gap> LocalActionGamma(4,F);
Group([ (1,5,9,10)(2,6,7,11)(3,4,8,12), (1,8)(2,7)(3,9)(4,5)(10,12) ])

gap> LocalActionGamma(3,SymmetricGroup(3));
Group([ (1,4,5)(2,3,6), (1,3)(2,4)(5,6) ])
gap> LocalActionGamma(2,3,SymmetricGroup(3));
Group([ (1,4,5)(2,3,6), (1,3)(2,4)(5,6) ])
gap> LocalActionGamma(3,3,SymmetricGroup(3));
Group([ (1,8,10)(2,7,9)(3,5,12)(4,6,11), (1,5)(2,6)(3,8)(4,7)(9,11)(10,12) ])

gap> F:=SymmetricGroup(3);;
gap> rho:=SignHomomorphism(F);;
gap> H:=LocalActionPi(2,3,F,rho,[1]);;
gap> z:=InvolutiveCompatibilityCocycle(H);;
gap> g:=LocalActionGamma(H,z);;
gap> [NrMovedPoints(g),TransitiveIdentification(g)];
[ 12, 8 ]

4.1-3 LocalActionDelta

for the arguments d, F

Returns: the group \Delta(F)\le\mathrm{Aut}(B_{d,2}).

The arguments of this method are a degree d \in\mathbb{N}_{\ge 3}, and a transitive subgroup F of S_{d}.

for the arguments d, F, C

Returns: the group \Delta(F,C)\le\mathrm{Aut}(B_{d,2}).

The arguments of this method are a degree d \in\mathbb{N}_{\ge 3}, a transitive subgroup F of S_d, and a central subgroup C of the stabilizer F_{1} of 1 in F.

gap> F:=SymmetricGroup(3);;
gap> D:=LocalActionDelta(3,F);
Group([ (1,3,6)(2,4,5), (1,3)(2,4), (1,2)(3,4)(5,6) ])
gap> F1:=Stabilizer(F,1);;
gap> D1:=LocalActionDelta(3,F,F1);
Group([ (1,4,5)(2,3,6), (1,3)(2,4)(5,6), (1,2)(3,4)(5,6) ])
gap> D=D1;
false
gap> G:=AutBall(3,2);;
gap> D^G=D1^G;
true

gap> F:=PrimitiveGroup(5,3);
AGL(1, 5)
gap> F1:=Stabilizer(F,1);
Group([ (2,3,4,5) ])
gap> C:=Group((2,4)(3,5));
Group([ (2,4)(3,5) ])
gap> Index(F1,C);
2
gap> Index(LocalActionDelta(5,F,F1),LocalActionDelta(5,F,C));
2

4.2 Maximal extensions

For any F\le\mathrm{Aut}(B_{d,k}) that satisfies (C), the group \Phi(F)\le\mathrm{Aut}(B_{d,k+1}) is the maximal extension of F that satisfies (C) as well. It stems from the action of \mathrm{U}_{k}(F) on balls of radius k+1 in T_{d}.

4.2-1 LocalActionPhi

for the argument F

Returns: the group \Phi_{k}(F)=\{(a,(a_{\omega})_{\omega})\mid a\in F,\ \forall \omega\in\Omega:\ a_{\omega}\in C_{F}(a,\omega)\}\le\mathrm{Aut}(B_{d,k+1}).

The argument of this method is a local action F \le\mathrm{Aut}(B_{d,k}).

for the arguments l, F

Returns: the group \Phi^{l}(F)=\Phi_{l-1}\circ\cdots\circ\Phi_{k+1}\circ\Phi_{k}(F)\le\mathrm{Aut}(B_{d,l}).

The arguments of this method are a radius l \in\mathbb{N} and a local action F \le\mathrm{Aut}(B_{d,k}).

gap> S3:=LocalAction(3,1,SymmetricGroup(3));;
gap> LocalActionPhi(S3);
Group([ (), (1,4,5)(2,3,6), (1,3)(2,4)(5,6), (1,2), (3,4), (5,6) ])
gap> last=AutBall(3,2);
true
gap> A3:=LocalAction(3,1,AlternatingGroup(3));;
gap> LocalActionPhi(A3);
Group([ (), (1,4,5)(2,3,6) ])
gap> last=LocalActionGamma(3,AlternatingGroup(3));
true

gap> S3:=LocalAction(3,1,SymmetricGroup(3));;
gap> groups:=ConjugacyClassRepsCompatibleGroupsWithProjection(2,S3);
[ Group([ (1,2)(3,5)(4,6), (1,4,5)(2,3,6) ]), 
  Group([ (1,2)(3,4)(5,6), (1,2)(3,5)(4,6), (1,4,5)(2,3,6) ]), 
  Group([ (3,4)(5,6), (1,2)(3,4), (1,4,5)(2,3,6), (3,5,4,6) ]), 
  Group([ (3,4)(5,6), (1,2)(3,4), (1,4,5)(2,3,6), (3,5)(4,6) ]), 
  Group([ (3,4)(5,6), (1,2)(3,4), (1,4,5)(2,3,6), (5,6), (3,5,4,6) ]) ]
gap> for G in groups do Print(Size(G),",",Size(LocalActionPhi(G)),"\n"); od;
6,6
12,12
24,192
24,192
48,3072

gap> LocalActionPhi(3,LocalAction(4,1,SymmetricGroup(4)));
<permutation group with 34 generators>
gap> last=AutBall(4,3);
true

gap> rho:=SignHomomorphism(SymmetricGroup(3));;
gap> F:=LocalActionPi(2,3,SymmetricGroup(3),rho,[1]);; Size(F);
24
gap> P:=LocalActionPhi(4,F);; Size(P);
12288
gap> IsSubgroup(AutBall(3,4),P);
true
gap> SatisfiesC(P);
true

4.3 Normal subgroups and partitions

When point stabilizers in F\le S_{d} are not simple, or F preserves a partition, more universal groups can be constructed as follows.

4.3-1 LocalActionPhi

for the arguments d, F, N

Returns: the group \Phi(F,N)\le\mathrm{Aut}(B_{d,2}).

The arguments of this method are a degree d \in\mathbb{N}_{\ge 3}, a transitive permutation group F \le S_{d} and a normal subgroup N of the stabilizer F_{1} of 1 in F.

for the arguments d, F, P

Returns: the group \Phi(F,P)=\{(a,(a_{\omega})_{\omega})\mid a\in F,\ a_{\omega}\in C_{F}(a,\omega) constant w.r.t. P\}\le\mathrm{Aut}(B_{d,2}).

The arguments of this method are a degree d \in\mathbb{N}_{\ge 3} and a permutation group F \le S_{d} and a partition P of [1..d] preserved by F.

for the arguments F, P

Returns: the group \Phi_{k}(F,P)=\{(\alpha,(\alpha_{\omega})_{\omega})\mid \alpha\in F,\ \alpha_{\omega}\in C_{F}(\alpha,\omega) constant w.r.t. P\}\le\mathrm{Aut}(B_{d,k+1}).

The arguments of this method are a local action F \le\mathrm{Aut}(B_{d,k}) and a partition P of [1..d] preserverd by \piF \le S_{d}. This method assumes that all compatibility sets with respect to a partition element are non-empty and that all compatibility sets of the identity with respect to a partition element are non-trivial.

gap> F:=SymmetricGroup(4);;
gap> F1:=Stabilizer(F,1);
Sym( [ 2 .. 4 ] )
gap> grps:=NormalSubgroups(F1);
[ Sym( [ 2 .. 4 ] ), Alt( [ 2 .. 4 ] ), Group(()) ]
gap> N:=grps[2];
Alt( [ 2 .. 4 ] )
gap> LocalActionPhi(4,F,N);
Group([ (1,5,9,10)(2,6,7,11)(3,4,8,12), (1,4)(2,5)(3,6)(7,8)(10,11), (1,2,3) ])
gap> Index(F1,N);
2
gap> Index(LocalActionPhi(4,F,F1),LocalActionPhi(4,F,N));
16

gap> F:=TransitiveGroup(4,3);
D(4)
gap> P:=Blocks(F,[1..4]);
[ [ 1, 3 ], [ 2, 4 ] ]
gap> G:=LocalActionPhi(4,F,P);
Group([ (1,5,9,10)(2,6,7,11)(3,4,8,12), (1,8)(2,7)(3,9)(4,5)(10,12), (1,3)
  (8,9), (4,5)(10,12) ])
gap> mt:=RandomSource(IsMersenneTwister,1);;
gap> aut:=Random(mt,G);
(1,3)(4,12)(5,10)(6,11)(8,9)
gap> LocalAction(1,4,2,aut,[1]); LocalAction(1,4,2,aut,[3]);
(2,4)
(2,4)
gap> LocalAction(1,4,2,aut,[2]); LocalAction(1,4,2,aut,[4]);
(1,3)(2,4)
(1,3)(2,4)

gap> H:=TransitiveGroup(4,3);
D(4)
gap> P:=Blocks(H,[1..4]);
[ [ 1, 3 ], [ 2, 4 ] ]
gap> F:=LocalActionPhi(4,H,P);;
gap> G:=LocalActionPhi(F,P);;
gap> SatisfiesC(G);
true

4.4 Abelian quotients

When a permutation group F\le S_{d} is not perfect, i.e. it admits an abelian quotient \rho:F\twoheadrightarrow A, more universal groups can be constructed by imposing restrictions of the form \prod_{r\in R}\prod_{x\in S(b,r)}\rho(\sigma_{1}(\alpha,x))=1 on elements \alpha\in\Phi^{k}(F)\le\mathrm{Aut}(B_{d,k}).

4.4-1 SignHomomorphism

Returns: the sign homomorphism from F to S_{2}.

The argument of this method is a permutation group F \le S_{d}. This method can be used as an example for the argument rho in the methods SpheresProduct (4.4-3) and LocalActionPi (4.4-4).

gap> F:=SymmetricGroup(3);;
gap> sign:=SignHomomorphism(F);
MappingByFunction( Sym( [ 1 .. 3 ] ), Sym( [ 1 .. 2 ] ), function( g ) ... end )
gap> Image(sign,(2,3));
(1,2)
gap> Image(sign,(1,2,3));
()

4.4-2 AbelianizationHomomorphism

Returns: the homomorphism from F to F/[F,F].

The argument of this method is a permutation group F \le S_{d}. This method can be used as an example for the argument rho in the methods SpheresProduct (4.4-3) and LocalActionPi (4.4-4).

gap> F:=PrimitiveGroup(5,3);
AGL(1, 5)
gap> ab:=AbelianizationHomomorphism(PrimitiveGroup(5,3));
[ (2,3,4,5), (1,2,3,5,4) ] -> [ f1, <identity> of ... ]
gap> Elements(Range(ab));
[ <identity> of ..., f1, f2, f1*f2 ]
gap> StructureDescription(Range(ab));
"C4"

4.4-3 SpheresProduct

Returns: the product \prod_{r\in R}\prod_{x\in S(b,r)}rho(\sigma_{1}(aut,x))\in\mathrm{im}(rho).

The arguments of this method are a degree d \in\mathbb{N}_{\ge 3}, a radius k \in\mathbb{N}, an automorphism aut of B_{d,k} all of whose 1-local actions are in the domain of the homomorphism rho from a subgroup of S_d to an abelian group, and a sublist R of [0..k-1]. This method is used in the implementation of LocalActionPi (4.4-4).

gap> rho:=SignHomomorphism(SymmetricGroup(3));;
gap> SpheresProduct(3,2,LocalActionElement(2,3,(1,2)),rho,[0]);
(1,2)
gap> SpheresProduct(3,2,LocalActionElement(2,3,(1,2)),rho,[0,1]);
()

gap> F:=PrimitiveGroup(5,3);
AGL(1, 5)
gap> rho:=AbelianizationHomomorphism(F);;
gap> Elements(Range(rho));
[ <identity> of ..., f1, f2, f1*f2 ]
gap> StructureDescription(Range(rho));
"C4"
gap> mt:=RandomSource(IsMersenneTwister,1);;
gap> aut:=Random(mt,F);
(1,4,3,5)
gap> SpheresProduct(5,3,LocalActionElement(3,5,aut),rho,[2]);
<identity> of ...
gap> SpheresProduct(5,3,LocalActionElement(3,5,aut),rho,[1,2]);
f1
gap> SpheresProduct(5,3,LocalActionElement(3,5,aut),rho,[0,1,2]);
f2

4.4-4 LocalActionPi

Returns: the group \Pi^{l}(F,rho,R)=\{\alpha\in\Phi^{l}(F)\mid \prod_{r\in R}\prod_{x\in S(b,r)}rho(\sigma_{1}(\alpha,x))=1\}\le\mathrm{Aut}(B_{d,l}).

The arguments of this method are a degree l \in\mathbb{N}_{\ge 2}, a radius d \in\mathbb{N}_{\ge 3}, a permutation group F \le S_d, a homomorphism \rho from F to an abelian group that is surjective on every point stabilizer in F, and a non-empty, non-zero subset R of [0..l-1] that contains l-1.

gap> F:=LocalAction(5,1,PrimitiveGroup(5,3));
AGL(1, 5)
gap> rho1:=AbelianizationHomomorphism(F);;
gap> rho2:=SignHomomorphism(F);;
gap> LocalActionPi(3,5,F,rho1,[0,1,2]);
<permutation group with 4 generators>
gap> Index(LocalActionPhi(3,F),last);
4
gap> LocalActionPi(3,5,F,rho2,[0,1,2]);
<permutation group with 5 generators>
gap> Index(LocalActionPhi(3,F),last);
2

4.5 Semidirect products

When a subgroup F\le\mathrm{Aut}(B_{d,k}) satisfies (C) and admits an involutive compatibility cocycle z (which is automatic when k=1) one can characterise the kernels K\le\Phi_{k}(F)\cap\ker(\pi_{k}) that fit into a z-split exact sequence 1\to K\to\Sigma(F,K)\to F\to 1 for some subgroup \Sigma(F,K)\le\mathrm{Aut}(B_{d,k+1}) that satisfies (C). This characterisation is implemented in this section.

4.5-1 CompatibleKernels

for the arguments d, F

Returns: the list of kernels K\le\prod_{\omega\in\Omega}F_{\omega}\cong\ker\pi\le\mathrm{Aut}(B_{d,2}) that are preserved by the action F \curvearrowright\prod_{\omega\in\Omega}F_{\omega}, a\cdot(a_{\omega})_{\omega}:=(aa_{a^{-1}\omega}a^{-1})_{\omega}.

The arguments of this method are a degree d \in\mathbb{N}_{\ge 3}, and a permutation group F \le S_{d}. The kernels output by this method are compatible with F with respect to the standard cocycle (see InvolutiveCompatibilityCocycle (5.3-1)) and can be used in the method LocalActionSigma (4.5-2).

for the arguments F, z

Returns: the list of kernels K\le\Phi_{k}(F)\cap\ker(\pi_{k})\le\mathrm{Aut}(B_{d,k+1}) that are normalized by \Gamma_{z}(F) and such that for all k\in K and \omega\in\Omega there is k_{\omega}\in K with \mathrm{pr}_{\omega}k_{\omega}=z(\mathrm{pr}_{\omega}k,\omega)^{-1}.

The arguments of this method are a local action F \le\mathrm{Aut}(B_{d,k}) that satisfies (C) and an involutive compatibility cocycle z of F (see InvolutiveCompatibilityCocycle (5.3-1)). It can be used in the method LocalActionSigma (4.5-2).

gap> CompatibleKernels(3,SymmetricGroup(3));
[ Group(()), Group([ (1,2)(3,4)(5,6) ]), Group([ (3,4)(5,6), (1,2)(5,6) ]), 
  Group([ (5,6), (3,4), (1,2) ]) ]

gap> P:=SymmetricGroup(3);;
gap> rho:=SignHomomorphism(P);;
gap> F:=LocalActionPi(2,3,P,rho,[1]);;
gap> z:=InvolutiveCompatibilityCocycle(F);;
gap> CompatibleKernels(F,z);
[ Group(()), Group([ (1,2)(3,4)(5,6)(7,8)(9,10)(11,12) ]), 
  Group([ (1,2)(3,4)(5,6)(7,8), (5,6)(7,8)(9,10)(11,12) ]), 
  Group([ (5,6)(7,8), (1,2)(3,4), (9,10)(11,12) ]) ]

4.5-2 LocalActionSigma

for the arguments d, F, K

Returns: the semidirect product \Sigma(F,K)\le\mathrm{Aut}(B_{d,2}).

The arguments of this method are a degree d \in\mathbb{N}_{\ge 3}, a subgroup F of S_{d} and a compatible kernel K for F (see CompatibleKernels (4.5-1)).

for the arguments F, K, z

Returns: the semidirect product \Sigma_{z}(F,K)\le\mathrm{Aut}(B_{d,k+1}).

The arguments of this method are a local action F of \mathrm{Aut}(B_{d,k}) that satisfies (C) and a kernel K that is compatible for F with respect to the involutive compatibility cocycle z (see InvolutiveCompatibilityCocycle (5.3-1) and CompatibleKernels (4.5-1)) of F.

gap> S3:=SymmetricGroup(3);;
gap> kernels:=CompatibleKernels(3,S3);
[ Group(()), Group([ (1,2)(3,4)(5,6) ]), Group([ (3,4)(5,6), (1,2)(5,6) ]), 
  Group([ (5,6), (3,4), (1,2) ]) ]
gap> for K in kernels do Print(Size(LocalActionSigma(3,S3,K)),"\n"); od;
6
12
24
48

gap> P:=SymmetricGroup(3);;
gap> rho:=SignHomomorphism(P);;
gap> F:=LocalActionPi(2,3,P,rho,[1]);;
gap> z:=InvolutiveCompatibilityCocycle(F);;
gap> kernels:=CompatibleKernels(F,z);
[ Group(()), Group([ (1,2)(3,4)(5,6)(7,8)(9,10)(11,12) ]), 
  Group([ (1,2)(3,4)(5,6)(7,8), (5,6)(7,8)(9,10)(11,12) ]), 
  Group([ (5,6)(7,8), (1,2)(3,4), (9,10)(11,12) ]) ]
gap> for K in kernels do Print(Size(LocalActionSigma(F,K,z)),"\n"); od;
24
48
96
192

4.6 PGL₂ over the p-adic numbers

Here, we implement functions to provide the k-local actions of the groups \mathrm{PGL}(2,\mathbb{Q}_{p}) and \mathrm{PSL}(2,\mathbb{Q}_{p}) acting on T_{p+1}. This section is due to Tasman Fell.

4.6-1 LocalActionPGL2Qp

Returns: the subgroup of \mathrm{Aut}(B_{p+1,k}) induced by the action of \mathrm{PGL}(2,\mathbb{Z}_{p}) on the ball of radius k around the vertex corresponding to the identity lattice of the Bruhat-Tits tree of \mathrm{PGL}(2,\mathbb{Q}_{p}).

The arguments of this method are a prime p and a radius k \in\mathbb{N}_{\ge 1}.

gap> LocalActionPGL2Qp(3,1)=SymmetricGroup(4);
true
gap> F:=LocalActionPGL2Qp(5,3);; Size(F);
1875000
gap> SatisfiesC(F);
true

4.6-2 LocalActionPSL2Qp

Returns: the subgroup of \mathrm{Aut}(B_{p+1,k}) induced by the action of \mathrm{PSL}(2,\mathbb{Z}_{p}) on the ball of radius k around the vertex corresponding to the identity lattice of the Bruhat-Tits tree of \mathrm{PGL}(2,\mathbb{Q}_{p}).

The arguments of this method are a prime p and a radius k \in\mathbb{N}_{\ge 1}.

gap> LocalActionPSL2Qp(3,1)=AlternatingGroup(4);
true
gap> F:=LocalActionPSL2Qp(5,3);; Size(F);
937500
gap> SatisfiesC(F);
true

generated by GAPDoc2HTML