GAP (SimplicialSurfaces) - Chapter 3: Access to the incidence geometry

In Section 2.1, we introduced incidence geometries to describe polygonal complexes. This chapter describes several different ways to access these incidence structures. Most of these methods are also applicable to twisted polygonal complexes. For more specific access to twisted polygonal complexes, compare Chapter 5.

In Section 3.1, the labeling conventions for vertices, edges, and faces are explained. The central incidence relations between them are described in Section 3.2. Some more specialized applications for incidence can be found in Chapter 10.

Finally the sections 3.3, 3.4, and 3.5 deal with variations of incidence that are usually not needed by the standard user.

3.1 Labels of vertices, edges and faces

In (twisted) polygonal complexes (the most general supported incidence structure, compare Chapter 2) all vertices, edges, and faces are labelled by positive integers.

These labels do not have to be consecutive or disjoint, as shown in the following example:

gap> complex := PolygonalComplexByDownwardIncidence( 
>        [ , [2,3], [2,5], , [3,7], [5,7] ], 
>        [ , , [2,3,5,6] ] );;

We can access the sets of all those labels by Vertices, Edges, and Faces. If only the number of vertices is relevant, we can use NumberOfVertices instead (likewise for edges and faces).

3.1-1 Vertices

gap> Vertices(complex);
[ 2, 3, 5, 7 ]
gap> NumberOfVertices(complex);
4

We have separated the operation Vertices from the corresponding attribute because there is a naming clash with the package grape.

3.1-2 Edges

gap> Edges(complex);
[ 2, 3, 5, 6 ]
gap> NumberOfEdges(complex);
4

3.1-3 Faces

gap> Faces(complex);
[ 3 ]
gap> NumberOfFaces(complex);
1

3.2 Incidence between vertices, edges, and faces

With the labels of vertices, edges and faces (which we can access by the methods of section 3.1) we can describe the incidence structure by lists of sets. All those methods have the form *Of*, e.g. VerticesOfFaces and EdgesOfVertices.

We will illustrate the general pattern of these methods by showcasing these two methods. For that we will use the following polygonal complex:

gap> complex := PolygonalComplexByDownwardIncidence( 
>    [ , , , , , [2,5], , [2,3], [3,5], [11,5], , [3,7], [7,11] ], 
>    [[6,8,9], , , [9,10,12,13]]);;
gap> Vertices(complex);
[ 2, 3, 5, 7, 11 ]
gap> Edges(complex);
[ 6, 8, 9, 10, 12, 13 ]
gap> Faces(complex);
[ 1, 4 ]

The method VerticesOfFaces tells us which vertices are incident to which faces.

gap> VerticesOfFaces(complex);
[ [ 2, 3, 5 ],,, [ 3, 5, 7, 11 ] ]

The first entry of this list contains a set of all vertices that are incident to face I. The second and third entries are not bound since there are no faces II and III. Finally, the fourth entry contains all vertices that are incident to face IV.

So, we have a list that contains sets of vertices and is indexed by the face labels.

The method EdgesOfVertices works in the same way: It returns a list that contains sets of edges and is indexed by the vertex labels.

gap> EdgesOfVertices(complex);
[ , [ 6, 8 ], [ 8, 9, 12 ],, [ 6, 9, 10 ],, [ 12, 13 ],,,, [ 10, 13 ] ]

For example, if we consider the third entry of this list, we find the set [ 8, 9, 12 ]. Those are all edges that are incident to the vertex 3.

3.2-1 EdgesOfVertices

The method EdgesOfVertex(complex, vertex) returns the set of all edges that are incident to vertex. The NC-version does not check whether the given vertex is a vertex of complex.

The attribute EdgesOfVertices(complex) collects all of those sets in a list that is indexed by the vertex labels, i.e. EdgesOfVertices(complex)[vertex] = EdgesOfVertex(complex, vertex). All other positions of this list are not bound.