The right-hand side of the formula $$\pi_3(SK(G,1)) \cong \ker (G\otimes G \rightarrow G, g\otimes g' \mapsto gg'g^{-1}g'^{-1})$$ involves a special case of a crossed module $$M\otimes N \rightarrow G, m\otimes n \mapsto (\partial m)(\partial'n)(\partial m)^{-1}(\partial' n)^{-1}$$ arising from two crossed modules $\partial\colon M\rightarrow G$ and $\partial'\colon N\rightarrow G$ with common target group $G$. Here $\otimes$ denotes the nonabelian tensor product introduced by Ronnie Brown and Jean-Louis Loday.

The following two commands construct the crossed modules $M\hookrightarrow G$ and $N\hookrightarrow G$ arising from two normal subgroups $M$, $N$ of the sylow 2-subgroup $G=Syl_2(M_{24})$ of the Mathieu group $M_{24}$, and then compute the homotopy groups $\pi_i(M\otimes N \rightarrow G)$ for $i=1,2$.


gap> G:=SylowSubgroup(MathieuGroup(24),2);;
      
gap> L:=NormalSubgroups(G);;

gap> M:=CrossedModuleByNormalSubgroup(G,L[100]);;

gap> N:=CrossedModuleByNormalSubgroup(G,L[101]);;

gap> T:=NonabelianTensorProduct(M,N);;

gap> StructureDescription(HomotopyGroup(T,1));

"((C2 x ((C2 x C2 x C2 x C2) : C2)) : C2) : C2"

gap> StructureDescription(HomotopyGroup(T,2));

"C2 x C2 x C2 x C2 x C2 x C2 x C2 x C2"

The above construction can be iterated. In particular, one can construct the triple tensor product $(G\otimes G)\otimes G \longrightarrow G$ for any group $G$. The following commands compute $$\exp((G\otimes G)\otimes G) = 4 \, ,$$ $$|(G\otimes G)\otimes G| = 1073741824 \, ,$$ for $G$ the 23rd group of order 32 in GAP's library of small groups.


gap> G:=SmallGroup(32,23);;

gap> K:=CrossedModuleByNormalSubgroup(G,G);;

gap> T2:=NonabelianTensorProduct(K,K);;

gap> T3:=NonabelianTensorProduct(T2,K);;

gap> T:=Source(T3!.map);;
  
gap> Exponent(T);

4

gap> Order(T);

1073741824

Corresponding to the nonabelian tensor product, there is a nonabelian exterior product $$M\wedge N \rightarrow G, m\wedge n \mapsto (\partial m)(\partial'n)(\partial m)^{-1}(\partial' n)^{-1}$$ arising from two crossed modules $\partial\colon M\rightarrow G$ and $\partial'\colon N\rightarrow G$ with common target group $G$. The exterior product is obtained from the tensor product by adding the relation $$m \otimes n = 1\ \ {\rm whenever}\ \partial m=\partial'n\,.$$

This exterior product can be iterated. In particular, one can construct the triple exterior product $(G\wedge G)\wedge G \longrightarrow G$ for any group $G$. The following commands compute $$\exp((G\wedge G)\wedge G) = 4 \, ,$$ $$|(G\wedge G)\wedge G| = 1024 \, ,$$ for $G$ the 23rd group of order 32 in GAP's library of small groups.


gap> G:=SmallGroup(32,23);;

gap> K:=CrossedModuleByNormalSubgroup(G,G);;

gap> E2:=NonabelianExteriorProduct(K,K);;

gap> E3:=NonabelianExteriorProduct(E2,K);;

gap> e:=Source(E3!.map);;

gap> Exponent(e);

4

gap> Order(e);

1024

About HAP: The nonabelian tensor product of crossed modules