Previous
 About HAP: Functorial Properties
 next

Homology is a functor. That is, for any n>0 and group homomorphism f : G → G' there is an induced homomorphism  Hn(f) : Hn(G,Z) → Hn(G',Z) satisfying
  • Hn(gf) = Hn(g)Hn(f) for group homomorphisms f : G → G', g : G' → G".
  • Hn(f) is the identity homomorphism if f is the identity.
The following commands compute H3(f) : H3(P,Z) → H3(S5,Z) for the inclusion f : P → S5 into the symmetric group S5 of its Sylow 2-subgroup. They also show that the image of the induced homomorphism H3(f) is precisely the Sylow 2-subgroup of H3(S5,Z).
gap>  S_5:=SymmetricGroup(5);;  P:=SylowSubgroup(S_5,2);;

gap>  f:=GroupHomomorphismByFunction(P,S_5, x->x);;

gap>  R:=ResolutionFiniteGroup(P,4);;

gap>  S:=ResolutionFiniteGroup(S_5,4);;

gap>  ZP_map:=EquivariantChainMap(R,S,f);;

gap>  map:=TensorWithIntegers(ZP_map);;

gap>  Hf:=Homology(map,3);;

gap>  AbelianInvariants(Image(Hf));
[2,4]

gap>  GroupHomology(G,3);
[2,12]
The above computation illustrates a general result.
 
For any Sylow p-subgroup P of a finite group G, the p-primary part of Hn(G,Z) is a quotient of Hn(P,Z).

We denote by Hn(G,Z)(p) the p-part of Hn(G,Z). This result follows from a property of the transfer homomorphism

Tr(G,K) : Hn(G,Z) → Hn(K,Z)

which exists for any group G and subgroup K<G of finite index |G:K|, and any n>0. The relevant property is the following.

The composed homomorphism 

Hn(K<G)oTr(G,K) : Hn(G,Z) → Hn(G,Z)

is just multiplication by the index |G:K|.
 
So in the case when K is a Sylow p-subgroup the composed homomorphism is an isomorphism on Hn(G,Z)(p) and, consequently, the induced homomorphism Hn(K→G,Z) must map surjectively onto Hn(G,Z)(p).

Another consequence of the transfer (with K=1) is that the exponent of Hn(G,Z) divides the order |G| for any finite group G. In particular, Hn(G,Z) is finite (since it is readily seen to be a finitely generated abelian group).

These results suggest that the homology Hn(G,Z) of a large finite group G (such as the Mathieu group G=M23) should be calculated by computing its p-part Hn(G,Z)(p) for each prime p dividing |G|. For a Sylow p-subgroup P there is a nice description of the kernel of the surjection Hn(P,Z) → Hn(G,Z)(p). It is generated by elements

hK(a)  -  hxKx-1(a)
 
where x ranges over the double coset representatives of P in G, K is the intersection of P and its conjugate xPx-1, the homomorphisms hK, hx-1Kx:Hn(K,Z) → Hn(P,Z) are induced by the inclusion K→P, k→k and the conjugated inclusion K→P, k→x-1kx,  and a ranges over the generators of  Hn(K,Z).

The function PrimePartDerivedFunctor(G,R,T,n) uses this description of the kernel to compute the abelian invariants of Hn(G,Z)(p) starting from:
  • the group G,
  • a ZP-resolution R for a Sylow p-subgroup P<G,
  • the functor T=TensorWithIntegers,
  • the integer n>0.
The following commands show that the Mathieu group M23 has third integral homology with 2-part H3(M23,Z)(2)=0.
gap> M_23:=MathieuGroup(23);;

gap> gens:=GeneratorsOfGroup(SylowSubgroup(M_23,2));;

gap> gensP:=[gens[4],gens[6],gens[2]];;   #This list generates a Sylow 2-subgroup of M_23.

gap> R:=ResolutionFiniteGroup(gensP,4);;

gap> T:=TensorWithIntegers;;

gap> PrimePartDerivedFunctor(M_23,R,T,3);
[  ]
Similar commands can be used to show that Hn(M23,Z)=0 for n=1,2,3,4.  The triviality of the first four integral homology groups of M23 was first proved in [J. Milgram, J. Group Theory, 2000] and answered a conjecture of J.-L. Loday. A group G is said to be k-connected if Hn(G,Z)=0 for n=1, 2, ..., k. Back in the mid 1970s Loday had asked if the trivial group is the only 3-connected finite group.

No example of a 5-connected finite group is yet known! A group is said to be superperfect if it is 2-connected. A list of some superperfect groups, together with their third integral homology, is given  here.

The higher dimensional integral homology of a group G is readily calculated by this method when G has no large Sylow subgroup. For example, the following commands show that the symmetric group of degree 5 has 20-dimensional integral homology H20(S5,Z) = (Z2)7 . (We could of course have incorporated into our computation the fact that cyclic Sylow groups have trivial integral homology in even dimensions.)
gap>  S_5:=SymmetricGroup(5);;

gap>  P2:=SylowSubgroup(S_5,2);;

gap>  P3:=SylowSubgroup(S_5,3);;

gap>  P5:=SylowSubgroup(S_5,5);;

gap>  R2:=ResolutionFiniteGroup(P2,21);;

gap>  R3:=ResolutionFiniteGroup(P3,21);;

gap>  R5:=ResolutionFiniteGroup(P5,21);;

gap> T:=TensorWithIntegers;;

gap>  PrimePartDerivedFunctor(S_5,R2,T,20);
[ 2, 2, 2, 2, 2, 2, 2 ]

gap>  PrimePartDerivedFunctor(S_5,R3,T,20);
[ ]

gap>  PrimePartDerivedFunctor(S_5,R5,T,20);
[ ]
Induced homology homomorphisms can be composed in HAP. For example, the following commands illustrate the functorial property Hn(gf) = Hn(g)Hn(f) for the inclusions f:A4→S4, g:S4→S5 and n=2.
gap> A4:=AlternatingGroup(4);;
gap> S4:=SymmetricGroup(4);;
gap> S5:=SymmetricGroup(5);;
gap>  f:=GroupHomomorphismByFunction(A4,S4,x->x);;
gap> g:=GroupHomomorphismByFunction(S4,S5,x->x);;
gap> gf:=Compose(g,f);;
gap> RA4:=ResolutionFiniteGroup(A4,3);;
gap> RS4:=ResolutionFiniteGroup(S4,3);;
gap> RS5:=ResolutionFiniteGroup(S5,3);;
gap> ef:=EquivariantChainMap(RA4,RS4,f);;
gap> eg:=EquivariantChainMap(RS4,RS5,g);;
gap> egf:=EquivariantChainMap(RA4,RS5,gf);;
gap>  tf:=TensorWithIntegers(ef);;
gap> tg:=TensorWithIntegers(eg);;
gap> tgf:=TensorWithIntegers(egf);;
gap> hf:=Homology(tf,2);;
gap> hg:=Homology(tg,2);;
gap> hgf:=Homology(tgf,2);;
gap> elt:=Random(Source(hf));;
gap> Image(hgf,elt)=Image(Compose(hg,hf),elt);
true
Previous Page
 Contents
 Next page